Vim

De Disposition de clavier bépo
Version datée du 13 février 2013 à 16:03 par Likorat (discussion | contributions) (Dans la section espace insécables; vim ne "voit" pas <S-Space> mais seulement le caractère généré, donce dans la ligne du inoremap, il faut directement mettre ce caractère)

Vim est un éditeur de texte ergonomique, libre et disponible sous de nombreux systèmes d'exploitation. Cette page tente de regrouper le maximum d'informations relatives à son utilisation avec la disposition bépo.

Ergonomie

Aide-mémoire Vim/bépo — version PDF

Pourquoi utiliser Vim ?

D'un point de vue ergonomique, Vim a été optimisé pour la prévention des troubles musculosquelettiques :

  • il n'utilise que très peu de raccourcis : plutôt que de recourir à des touches modificatrices (Ctrl, Alt ou la touche Meta), il utilise plusieurs « modes » de fonctionnement (quatre modes : normal, insertion, visualisation et commande), ce qui permet d'utiliser toutes les commandes en position « dactylo », c'est-à-dire avec les doigts proches de la position de repos, prêt à taper du texte à tout instant ;
  • les déplacements du curseur peuvent (devraient, à terme) se faire sans utiliser les flèches du clavier ou la souris : clavier azertyH clavier azertyJ clavier azertyK clavier azertyL déplacent le curseur case par case, clavier azertyW clavier azertyE clavier azertyB déplacent le curseur mot à mot (équivalent à clavier bépoCtrl+clavier bépoflèche). Les mains restent ainsi en position dactylo pour toutes les manipulations de texte, y compris les déplacements.

L'utilisation des différents modes de Vim permet de se passer complètement de la souris et d'éliminer la plupart des raccourcis contraignants qui brisent la frappe, tout en diminuant les mouvements de main et la quantité de touches pressées dans la journée.

Le prix à payer est un temps d'apprentissage assez long — plus long que sur n'importe quel autre éditeur de texte. Toutefois, lorsqu'on maîtrise les bases de Vim, le gain en confort et en productivité est tel qu'on n'utilise plus aucun autre éditeur — et on finit même par souhaiter « Vimifier » les applications bureautiques courantes pour profiter de cette ergonomie sur l'ensemble du poste de travail. Hors, les bases de Vim ne sont pas difficiles à apprendre, notamment parce qu'il existe de bons tutoriels « par l'exemple »… et que vous utilisez la disposition bépo !

Là où le bât blesse, c'est que Vim a été conçu pour un clavier Qwerty (contexte américain) :

  • le fait que les touches clavier azertyH clavier azertyJ clavier azertyK clavier azertyL correspondent à clavier bépoC clavier bépoT clavier bépoR clavier bépoS complique singulièrement la vie des bépoïstes, même pour les « Vimistes » convaincus ;
  • Vim n'est pas parfaitement utilisable en l'état avec le Bépo, contrairement à l'Azerty ou même le Dvorak-US, essentiellement parce que les touches clavier bépoJ et clavier bépoK ne sont pas côte-à-côte.

Il convient donc de configurer Vim pour l'utiliser en Bépo – c'est l'objectif de cette page.

Tutoriels et ressources Vim

L'installation de Vim donne accès à un tutoriel spécialement étudié pour les débutants (mais qui fait une très bonne doc de rappel pour les moins débutants). Il est accessible en français par la commande 

vimtutor fr

Le principe est le suivant : un fichier texte est ouvert dans Vim et présente les bases de Vim. Vous êtes invité à modifier sur place ce fichier, c'est-à-dire à tester les commandes et les exemples décrits dans le fichier. Comme le fichier modifié est en réalité une copie du tutorial, vous pouvez à tout moment relancer vimtutor pour repartir sur une version propre, si vous en arrivez à faire n'importe quoi ou à bloquer dans un mode !

Reconfiguration partielle des touches

On ne cherche ici qu'à implémenter le déplacement en clavier azertyH clavier azertyJ clavier azertyK clavier azertyL avec le moins d'impact possible sur le reste des commandes Vim.

Aide-mémoire Vim/bépo — version PDF

Principe

  • clavier bépoC clavier bépoT clavier bépoS clavier bépoR remplacent clavier azertyH clavier azertyJ clavier azertyK clavier azertyL pour les touches de direction ;
  • réciproquement :
    • clavier bépoH remplace clavier azertyR (remplacer)
    • clavier bépoJ remplace clavier azertyT (jusqu'à)
    • clavier bépoK remplace clavier azertyS (substitue)
    • clavier bépoL remplace clavier azertyC ('modification de texte), juste à coté de clavier bépoD (couper)
  • clavier bépoÉ remplace clavier azertyW (mot suivant), le clavier bépoW étant beaucoup trop loin en bépo ;
  • clavier bépoW est utilisé comme clavier bépoCtrl+clavier bépoW pour faciliter les manipulations de fenêtre.

C'est la solution la plus simple pour utiliser Vim confortablement en bépo.

~/.vimrc

Créer un fichier ~/.vimrc.bepo avec le contenu suivant : 

" {W} -> [É]
" ——————————
" On remappe W sur É :
noremap é w
noremap É W
" Corollaire, pour effacer/remplacer un mot quand on n’est pas au début (daé / laé).
" (attention, cela diminue la réactivité du {A}…)
noremap aé aw
noremap aÉ aW
" Pour faciliter les manipulations de fenêtres, on utilise {W} comme un Ctrl+W :
noremap w <C-w>
noremap W <C-w><C-w>

" [HJKL] -> {CTSR}
" ————————————————
" {cr} = « gauche / droite »
noremap c h
noremap r l
" {ts} = « haut / bas »
noremap t j
noremap s k
" {CR} = « haut / bas de l'écran »
noremap C H
noremap R L
" {TS} = « joindre / aide »
noremap T J
noremap S K
" Corollaire : repli suivant / précédent
noremap zs zj
noremap zt zk

" {HJKL} <- [CTSR]
" ————————————————
" {J} = « Jusqu'à »            (j = suivant, J = précédant)
noremap j t
noremap J T
" {L} = « Change »             (l = attend un mvt, L = jusqu'à la fin de ligne)
noremap l c
noremap L C
" {H} = « Remplace »           (h = un caractère slt, H = reste en « Remplace »)
noremap h r
noremap H R
" {K} = « Substitue »          (k = caractère, K = ligne)
noremap k s
noremap K S
" Corollaire : correction orthographique
noremap ]k ]s
noremap [k [s

" Désambiguation de {g}
" —————————————————————
" ligne écran précédente / suivante (à l'intérieur d'une phrase)
noremap gs gk
noremap gt gj
" onglet précédant / suivant
noremap gb gT
noremap gé gt
" optionnel : {gB} / {gÉ} pour aller au premier / dernier onglet
noremap gB :exe "silent! tabfirst"<CR>
noremap gÉ :exe "silent! tablast"<CR>
" optionnel : {g"} pour aller au début de la ligne écran
noremap g" g0

" <> en direct
" ————————————
noremap « <
noremap » >

" Remaper la gestion des fenêtres
" ———————————————————————————————
noremap wt <C-w>j
noremap ws <C-w>k
noremap wc <C-w>h
noremap wr <C-w>l
noremap wd <C-w>c
noremap wo <C-w>s
noremap wp <C-w>o
noremap w<SPACE> :split<CR>
noremap w<CR> :vsplit<CR>

Si vous souhaitez avoir les chiffres en accès direct en mode normal, remplacez la section « <> en direct » par les lignes suivantes : 

" Chiffres en accès direct
" ————————————————————————
noremap " 1
noremap 1 "
noremap « 2
noremap 2 <
noremap » 3
noremap 3 >
noremap ( 4
noremap 4 (
noremap ) 5
noremap 5 )
noremap @ 6
noremap 6 @
noremap + 7
noremap 7 +
noremap - 8
noremap 8 -
noremap / 9
noremap 9 /
noremap * 0
noremap 0 *

Puis ajoutez la ligne suivante dans le fichier ~/.vimrc : 

source ~/.vimrc.bepo

Nota : les utilisateurs de Vimperator peuvent ajouter la même ligne dans le fichier ~/.vimperatorrc.

~/.vim/after/ftplugin/netrw.vim

Ex est le plugin d'exploration de fichiers de Vim. On le lance avec « :Ex », « :Sex », « :Vex », « :Tex », ou même « :e . ».

Malheureusement, clavier bépot et clavier bépos ne fonctionnent pas comme « bas/haut » avec cet explorateur, car les mappings d'Ex ne sont pas définis dans ~/.vimrc. Deux solutions :

  • utiliser les flèches plutôt que clavier bépoC clavier bépoT clavier bépoS clavier bépoR avec Ex — voire, au pire, utiliser la souris (sacrilège !)
  • redéfinir les commandes d'Ex dans le fichier ~/.vim/after/ftplugin/netrw.vim comme suit :
nunmap <buffer> t
nunmap <buffer> s
nunmap <buffer> k
nnoremap <buffer> t j
nnoremap <buffer> s k
nnoremap <buffer> k s

Avec ce fichier, clavier bépoT et clavier bépoS fonctionnent désormais comme bas/haut et clavier bépoK permet de changer le type de tri (par nom, par date, etc.). Attention, l'aide affichée par Ex ne correspond plus à la réalité !

Remarques

Les touches clavier bépoÊ clavier bépoÈ clavier bépoÀ clavier bépoÇ sont inutilisées par Vim et peuvent donc être affectées librement. Par exemple, on peut faire de clavier bépoÈ une touche « début de ligne » : 

noremap è ^
noremap È 0

Le guillemet-apostrophe (rsqm) en direct ne peut pas être réaffecté en une apostrophe droite (probablement parce que le rqsm n'est pas disponible en Latin-1). Par contre, les adeptes du guillemet-apostrophe en accès direct peuvent utiliser la touche clavier bépoç à cet effet : 

noremap ç '
noremap Ç `

À faire pour la prochaine version (0.6.7) :

  • inverser clavier bépoj et clavier bépoh pour regrouper les fonctions de recherche de caractères sur une même ligne ;
  • penser à mettre à jour le label de {;/:} ;
  • remplacer <> par «» sur les touches clavier bépo2 clavier bépo3 ?

Par ailleurs, on pourrait échanger clavier bépos et clavier bépog de façon à avoir clavier bépog sous la main gauche et pour une meilleure cohérence des raccourcis de Vim : les commandes correspondant à « s » et « r », respectivement clavier bépog et clavier bépoh, se trouveraient alors sous les touches clavier bépoS et clavier bépoR. problématique pour les raccourcis en clavier bépog, nécessite une série de remappages supplémentaires, et conflit avec l'inversion clavier bépoj/clavier bépoh.

Problèmes connus

Avec le greffon « Automatic LaTeX Plugin » (ATP)

En installant le plugin ATP pour LaTeX, le mapping de la touche clavier bépor revient à son réglage normal et il est impossible de forcer son utilisation au mouvement vers la gauche par les configurations ci-dessus.

Pour y remedier, il faut ajouter au fichier .vim/after/ftplugin/tex.vim, la ligne "noremap <buffer> r l".

Reconfiguration à la demande

Mettre le script suivant dans ~/.vim/plugin/dvorak-toggle. Avec un minimum d'adaptation, il est possible gérer n'importe quelle disposition. 

" Quick Dvorak-layout toggle. 
" when toggled, you can use ctsr to move 
" when untoggled, ctsr will behave as expected by vim 
" 
" This code is under BSD licence, and the author doesn't even bother tell his identity.

let s:DvorakToggleState = 0
let s:DvorakToggleOldMap = 0

function! g:DvorakToggle () 
  if s:DvorakToggleState 
    :set langmap=s:DvorakToggleOldMap 
    let s:DvorakToggleState = 0 
  else  
    let g:DvorakToggleOldMap = &langmap 
    :set langmap=ctsrCTSRhjklHJKL;hjklHJKLctsrCTSR 
    let s:DvorakToggleState = 1 
  endif 
endfunction 

" use à or whatever you want. Make it easy to access though. 
nmap à :call g:DvorakToggle()<CR>

Reconfiguration conditionnelle

Il est parfois possible détecter depuis Vim si votre disposition préférée est en place (pour ceux qui ne peuvent ou ne veulent s’en servir systématiquement).

Sous X

if !empty(system("setxkbmap -print|grep bepo"))
    source ~/.vimrc.bepo
endif


Reconfiguration totale des touches

Une option radicale consisterait à reconfigurer toutes les touches en mode normal afin qu'elles correspondent aux labels du clavier Azerty. On pourrait même envisager de générer automatiquement un tel fichier avec les outils du projet bépo, si suffisamment d'utilisateurs étaient intéressés…

Bépo/Qwerty

Aide-mémoire Vim/bépo avec mapping du clavier bépo -> qwerty en mode normal

C'est à priori la meilleure solution du point de vue de l'ergonomie. On peut reprendre les cheat sheets (anti-sèches) classiques en l'état ! 

""
"" mapping du clavier bépo->qwerty en mode normal
""

" configuration des lettres

noremap b q
noremap é w
noremap p e
noremap o r
noremap è t
noremap ^ y
noremap v u
noremap d i
noremap l o
noremap j p
noremap z [
noremap w ]
noremap a a
noremap u s
noremap i d
noremap e f
noremap \ \
noremap g ,
noremap c h
noremap t j
noremap s k
noremap r l
noremap n ;
noremap m '
noremap ê <
noremap à z
noremap àà zz
noremap y x
noremap x c
noremap . v
noremap k b
noremap ' n
noremap q m
noremap g ,
noremap , g
noremap ,, gg
noremap h .
noremap f /
noremap B Q
noremap É W
noremap P E
noremap O R
noremap È T
noremap ! Y
noremap V U
noremap D I
noremap L O
noremap J P
noremap Z {
noremap W }
noremap A A
noremap U S
noremap I D
noremap E F
noremap ; G
noremap C H
noremap T J
noremap S K
noremap R L
noremap N :
noremap M "
noremap Ç \|
noremap Ê >
noremap À Z
noremap ÀÀ ZZ
noremap Y X
noremap X C
noremap : V
noremap K B
noremap ? N
noremap Q M
noremap G <
noremap H >
noremap F ?

" configuration du copié sur le ç car y est sur la touche composé ^

noremap ç y

" configuration des nombres

noremap $ `
noremap " 1
noremap « 2
noremap » 3
noremap ( 4
noremap ) 5
noremap @ 6
noremap + 7
noremap - 8
noremap / 9
noremap * 0
noremap = -
noremap % =
noremap # ~
noremap 1 !
noremap 2 @
noremap 3 #
noremap 4 $
noremap 5 %
noremap 6 ^
noremap 7 &
noremap 8 *
noremap 9 (
noremap 0 )
noremap ° _
noremap ` +

Bépo/Azerty

Cette variante permet de se référer aux labels des touches du clavier Azerty pour les commandes Vim. 

set langmap=ba,éz,pe,or,èt,çy,vu,di,lo,fp,j^,z$,aq,us,id,ef,\,g,ch,tj,sk,nl,rm,mù,^*,ê<,àw,hx,yc,.v,kb,'n,q\,,g;;,x:,w!,BA,ÉZ,PE,OR,ÈT,ÇY,VU,DI,LO,FP,J¨,Z£,AQ,US,ID,EF,?G,CH,TJ,SK,NL,RM,M%,!*,Ê>,ÀW,HX,YC,:V,KB,\\;N,QG,G.,X/,W§,@œ,_&,"é,«",»',((,)-,+è,-_,*ç,/à,=),%=,$Œ,^°,µ+,#“,{´,}~,<#,>{,[[,]|,±`,¬\,×^,÷@,¯],%}

Autres options utiles

Quelques petites astuces. À ajouter dans le fichier ~/.vimrc.

Appliquer automatiquement les modifications de ~/.vimrc

La première chose à faire pour jouer avec ~/.vimrc ! 

if has("autocmd")
  autocmd! bufwritepost .vimrc source ~/.vimrc
endif

Note : cette astuce semble ne pas fonctionner pour certains. Si vous constatez des problèmes, passez-vous en et relancez Vim après chaque modification de ~/.vimrc que vous voulez tester…

Espaces insécables

Les espaces insécables du Bépo peuvent poser problème, notamment dans des fichiers de code brut (ASCII) où ils génèrent des erreurs. On a deux façons simples de s’en prémunir :

Colorier les espaces insécables pour mieux les repérer

Ajouter les lignes suivantes après la ligne « syntax on » le cas échéant. Bien entendu, on peut changer la couleur. 

" colorise les nbsp
highlight NbSp ctermbg=lightgray guibg=lightred
match NbSp /\%xa0/
Faire apparaître les insécable avec un autre caractère

Ils apparaitront avec le caractère choisi au bout de la première ligne. Ici le « · » 

set listchars=nbsp:·
set list

Autre exemple trouvé sur Gnusquad avec plus de caractères « invisibles » affichés : 

set listchars=nbsp:¤,tab:>-,trail:¤,extends:>,precedes:<
set list
Mapper l’espace insécable en « Escape »

à éviter pour rédiger du texte mais très pratique pour taper du code ! 

" interdit les nbsp en mode insertion (il y a une espace insécable)
inoremap   <Esc>

[Esc] plus accessible

Vim fait un grand usage de la touche clavier azertyEscape qui se trouve loin (a priori en haut à gauche). On peut modifier le comportement de clavier bépoTab pour qu’il serve de touche clavier bépoÉchap. On garde un clavier bépoTab en clavier bépoMaj+clavier bépoTab. Attention, à ne pas utiliser dans Vimperator, on y a besoin du Tab direct…

Note : clavier bépoCtrl+clavier bépoC est un alias standard de clavier bépoÉchap, plus central, mais c'est un raccourci à deux touches. À vous de voir si cette combinaison est agréable ou pas sur votre clavier physique. 

" Tab fait un Esc, Maj+Tab fait un Tab
inoremap <Tab> <Esc>
inoremap &lt;S-Tab> <Tab>

" Même chose, mais en mode visuel
vnoremap <Tab> <Esc>
vnoremap &lt;S-Tab> <Tab>

Les possesseurs de clavier TypeMatrix peuvent aussi remapper la touche « desktop » en Esc en suivant les explications présentées sur la page dédiée au TypeMatrix.

[PgUp] / [PgDn] plus accessibles

Vim utilise par défaut clavier azertyCtrl+clavier azertyB et clavier azertyCtrl+clavier azertyF pour aller à la page précédente ou suivante. Ce n'est déjà pas la panacée en Qwerty, mais en Bépo, c'est l'horreur, car ces deux touches sont à l'exact opposé l'une de l'autre ! Pour y remédier, on peut par exemple utiliser les touches clavier bépoBackSpace et clavier bépoEspace, c'est bien plus confortable : 

noremap <BS> <PageUp>
noremap <Space> <PageDown>

Alternativement, si on préfère défiler des demi-pages, on peut utiliser les mappings suivants : 

noremap <BS> <C-U>
noremap <Space> <C-D>

Tant qu'on y est, on peut aussi utiliser clavier bépoEntrée pour centrer la page sur le curseur (ne fonctionne pas avec Vimperator) : 

 noremap <Return> zz

Fixer l’encodage des fichiers en utf-8

 set encoding=utf-8
 set fileencoding=utf-8

Plus de détails ici.

Lancer un navigateur web depuis Vim

Hors sujet, mais vraiment belle astuce. 

" « v,d » et « v,s » lancent firefox et une recherche (définition ou synonyme) dans le tlfi sur le mot courant
vmap ,d :<C-U>!firefox "http://www.cnrtl.fr/lexicographie/<cword>" >& /dev/null<CR><CR>
vmap ,s :<C-U>!firefox "http://www.cnrtl.fr/synonymie/<cword>" >& /dev/null<CR><CR>
" « v,g » comme ci-dessus mais pour google
vmap ,g :<C-U>!firefox "http://www.google.fr/search?hl=fr&q=<cword>&btnG=Recherche+Google&meta=" >& /dev/null<CR><CR>
"« v,w » comme ci-dessus mais pour wikipedia
vmap ,w :<C-U>!firefox "http://fr.wikipedia.org/wiki/<cword>" >& /dev/null<CR><CR>
" « v,c » comme ci-dessus mais pour le conjugueur
vmap ,c :<C-U>!firefox "http://www.leconjugueur.com/php5/index.php?v=<cword>" >& /dev/null<CR><CR>
" « v,o » ouvre l’url sur laquelle on se trouve dans firefox
vmap ,o :<C-U>!firefox "<cfile>" >& /dev/null<CR><CR>

Il faut que Firefox soit dans le $PATH, sinon, il faut indiquer le chemin complet de l’exécutable. Les raccourcis proposés sont tous en « ,x » pour qu’il n’y ait pas d’interaction malencontreuse avec d’autres commandes, mais on peut changer cette partie.

Variante qui tue, en utilisant un navigateur texte à l'intérieur de Vim :

  • enregistrer browser.vim dans le dossier ~/.vim/plugin/
  • facultatif : remplacer « lynx » par « w3m » partout dans le fichier browser.vim (w3m supporte l'utf-8, contrairement à lynx)
  • ajouter les lignes suivantes dans le fichier ~/.vimrc :
" « v,d » cherche la définition du mot courant dans le TLFI
vmap ,d :call OpenWebBrowser("http://www.cnrtl.fr/lexicographie/<C-R><C-W>")<CR>
" « v,s » cherche les synonymes du mot courant dans le TLFI
vmap ,s :call OpenWebBrowser("http://www.cnrtl.fr/synonymie/<C-R><C-W>")<CR>
" « v,g » cherche le mot courant dans Google
vmap ,g :call OpenWebBrowser("http://www.google.fr/search?hl=fr&q=<C-R><C-W>&btnG=Recherche+Google&meta=")<CR>
" « v,c » cherche le mot courant dans le conjugueur
vmap ,c :call OpenWebBrowser("http://www.leconjugueur.com/php5/index.php?v=<C-R><C-W>")<CR>
" « v,w » cherche le mot courant Wikipedia
vmap ,w :call OpenWebBrowser("http://fr.wikipedia.org/wiki/<C-R><C-W>")<CR>
" ouvre l’URL sur laquelle on se trouve
vmap ,o :call OpenWebBrowser("<C-R><C-A>")<CR>

Les URLs proposées ici correspondent à un usage de Vim en traitement de texte ; les développeurs auront tôt fait de remplacer ces URLs par des documentations d'API en ligne.

Exemples de ~/.vimrc

« Bépo-Vimification » du poste de travail

Bon nombre d'applications courantes utilisent les touches de déplacement de Vim, sans toutefois utiliser le fichier ~/.vimrc pour la configuration de ces touches. Moyennant un effort de configuration, on peut donc disposer d'un mode Vim, avec les touches de déplacement en {CTSR}, sur l'ensemble de son poste de travail.

Navigateurs web

Uzbl

Uzbl (prononcez "usable") est un navigateur web qui se pilote entièrement au clavier avec les raccourcis clavier de vim. Fondé sur webkit, uzbl est beaucoup plus léger que vimperator.

Firefox

Vimperator est une extension Firefox permettant de piloter confortablement Firefox au clavier, et même d'utiliser Vim comme éditeur pour les champs texte. Elle peut partager une partie de son fichier de configuration avec Vim (v. plus haut), il suffit d'ajouter cette ligne au fichier ~/.vimperatorrc : 

source ~/.vimrc.bepo

Une aide sur l'utilisation bépo de vimperator est disponnible sur cette page.

À noter : Vimperator est conçu pour fonctionner avec les chiffres en accès direct, ce qui est gênant (mais pas insurmontable) pour sélectionner des liens via le mécanismes de quick hints (clavier bépof et clavier bépoF). Le mapping proposé pour avoir les chiffres en accès direct dans Vim ne fonctionne pas avec Vimperator.

Voir le wiki de Vimperator pour plus d'informations sur la configuration.

Voir également GViMail pour utiliser Vimperator avec Gmail.

Chrome / Chromium

Il existe plusieurs extensions visant à émuler les commandes Vim sous Chrome. On peut citer YakShave, Vrome et Vimium. Les deux premières sont assez complexes mais extensivement configurables via un serveur à lancer en tâche de fond — indépendamment de Chrome. La dernière a le mérite de rester simple et de remplir assez bien son office. Voici de quoi lui apprendre à se comporter un peu mieux en bépo (lignes à copier dans la section « Adanced options >> Key mappings » des réglages de l’extension): 

map t scrollDown
map s scrollUp
map c scrollLeft
map r scrollRight
map j createTab
map gé nextTab
map gb previousTab
map h reload

À noter : une extension apparue plus récemment, Vichrome, mérite le détour. Elle paraît mieux finie que les précédentes. Si vous souhaitez l’utiliser en bépo, ces lignes sont un bon point de départ (ajoutez-les à la section « Key Mapping » des options de l’extension) : 

# bépo
nmap t ScrollDown
nmap s ScrollUp
nmap c ScrollLeft
nmap r ScrollRight
nmap j TabOpenNew
nmap gé TabFocusNext
nmap gb TabFocusPrev
nmap h TabReload

Thunderbird

Muttator est l'équivalent de Vimperator pour Thunderbird. Le projet est encore en début de développement, mais serait d'ores et déjà utilisable (non testé).

À compléter.

IDEs

Vim n'est qu'un éditeur texte, pas un IDE. Cependant, la plupart des IDEs disposent d'un mode Vi, nativement ou non.

Emacs

Emacs dispose nativement d'un mode Vi qui le rend utilisable permet de déplacer le curseur sans bouger les mains (pas testé ;-)).

Komodo

Komodo et OpenKomodo disposent nativement d'un mode Vi.

Eclipse

il y a un plugin Vim pour Eclipse ; il y a aussi le projet Eclim, qui permet d'utiliser Vim comme éditeur de texte dans Eclipse.

Visual Studio™

ViEmu propose un plugin Vim (non-libre) pour Visual Studio, ainsi que pour Word™ et Outlook™.

Pida

Pida utilise nativement vim ou bien Emacs.

Outils du shell

De nombreux outils courants du shell utilisent nativement les raccourcis Vim :

  • less : le pager le plus courant de nos jours, qui succède avantageusement à more ; c'est lui qui met en forme les pages man, notamment. Il est configurable via lesskey.
  • most : un pager plus puissant encore qui peut être utilisé à la place de less pour les pages de man.
  • aptitude : le gestionnaire de paquets Debian est configurable lui aussi.
  • w3m : navigateur web, moins connu que Lynx, mais qui a néanmoins l'avantage d'être compatible utf-8, entre autres. On peut redéfinir les raccourcis clavier dans le fichier ~/.w3m/config.
  • mutt : client mail. On peut utiliser ses propres mappings (exemple).
  • muttng : fork de mutt, qui inclut un certain nombre de patches et qui serait plus configurable (exemple).
  • Newsbeuter : Agrégateur de flux de syndication en console fonctionnant comme mutt. Il est possible de redéfinir les binding pour les adapter à bépo.
  • ranger : un explorateur de fichier avec interface légère utilisable au clavier. La configuration des raccourcis se fait dans le fichier ~/.config/ranger/rc.conf . Pour créer ce fichier et les autres fichiers de conf utiliser la commande : ranger --copy-config=all

Les plus gravement atteints peuvent utiliser des raccourcis Vi dans le terminal :

  • en modifiant le fichier ~/.inputrc
  • en utilisant zsh, qui possède un mode vi ; il suffit d'ajouter les lignes suivantes au fichier ~/.zshrc :
 # Mode vim
 bindkey -v
 
 # On remappe pour le bépo
 bindkey -a c vi-backward-char
 bindkey -a r vi-forward-char
 bindkey -a t vi-down-line-or-history
 bindkey -a s vi-up-line-or-history
 bindkey -a $ vi-end-of-line
 bindkey -a 0 vi-digit-or-beginning-of-line 
 bindkey -a h vi-change
 bindkey -a H vi-change-eol
 bindkey -a dd vi-change-whole-line
 bindkey -a l vi-replace-chars
 bindkey -a L vi-replace
 bindkey -a k vi-substitute

Sous X, il est parfois possible détecter si votre disposition préférée est en place (pour ceux qui ne peuvent ou ne veulent s’en servir systématiquement). Il suffit d’enfermer les bindkey dans un bloc if : 

if [[ $DISPLAY != '' && `setxkbmap -print|grep bepo` != '' ]]; then
    ...
fi

D'autres applications utilisent les raccourcis Vi mais ne sont pas remappables. Vous pouvez toujours contacter leurs auteurs pour leur demander d'inclure un mécanisme de mapping, ou recompiler ces outils avec des mappings bépo.

  • vifm : très bon explorateur de fichiers, en pleine phase de développement.
  • cmus : lecteur audio. Le site officiel précise qu'il supporte des dynamic keybindings, (adaptation à bépo).
  • dvtm : permet de scinder n’importe quel émulateur de terminal à la manière d’un gestionnaire de fenêtres en mosaïque. Tout simplement génial, notamment en conjonction avec Vim, mais il faut le recompiler pour changer les raccourcis clavier.

Lecteurs PDF

Certains lecteurs PDF s’utilisent avec des raccourcis « vim-like » :

  • Zathura est un lecteur PDF en apparence léger mais utilisant des bibliothèques lourdes en réalité ce qui n’ôte rien à ses qualités. Pour l’utiliser avec BÉPO il nécessite quelques configurations.
  • Evince est le lecteur PDF du projet GNOME, il dispose de quelques fonctionnalités vim-like, reste à savoir comment le « bépoïfier ».

Gestionnaires de fenêtres en mosaïque

Ces gestionnaires de fenêtres sont des alternatives intéressantes pour ceux qui cherchent à se passer complètement de la souris. Ils sont conçus exclusivement pour la productivité : pas de décorations de fenêtre, les fenêtres sont placées automatiquement par le gestionnaire pour occuper tout l'espace disponible : typiquement, une fenêtre « maître » qui occupe une large colonne de l'écran, et toutes les autres fenêtres « auxiliaires » qui se partagent l'espace restant. Le lancement des applications et les manipulations de fenêtres (sélection, déplacement, passage d'une fenêtre auxiliaire en maître) se font entièrement au clavier.

On peut citer Ion (le plus connu) et Ratpoison/StumpWM (le second est une ré-écriture en CommonLisp du premier, par le même auteur), mais ces gestionnaires de fenêtres sont un peu hors-sujet dans la mesure où ils utilisent une logique de raccourcis clavier de type Emacs. À l'inverse, d'autres gestionnaires de fenêtres utilisent nativement des raccourcis Vim de type [Mod]+[HJKL] pour les manipulations de fenêtres, et s'intègrent très bien dans un environnement « vimiste ».

wmii

wmii est le plus facile à prendre en main. C'est le seul de ces gestionnaires de fenêtres en mosaïque à conserver des décorations de fenêtres (très minimalistes, sans icone), ce qui permet de déplacer et redimensionner les fenêtres uniquement à la souris, et, plus prosaïquement, de repérer très facilement la fenêtre active. C'est aussi le seul à ne pas utiliser le concept de zones maître/auxiliaire : il est possible de créer autant de colonnes que souhaité, par contre leur redimensionnement requiert la souris. Ainsi, l'utilisation de logiciels comportant de nombreuses fenêtres (ex : GIMP) ne pose aucun problème, même en mode mosaïque. Il intègre un excellent lanceur d'applications, dmenu (activé avec Alt+P).

Il est aisément configurable via le fichier wmiirc.

dwm

dwm est le petit frère de wmii : les deux projets sont développés en parallèle par le même auteur. dwm partage certains outils avec wmii, dont dmenu. Toutefois, les deux projets sont assez différents, dwm étant encore plus minimaliste : aucune décoration de fenêtre, la mise en page est limitée à deux colonnes (une zone « maître » et une zone auxiliaire), aucun langage de script, aucun fichier de configuration. Le code source est ainsi encore plus robuste et compact (limité à 2 000 lignes, contre 10 000 pour wmii).

dwm doit être recompilé pour toute modification de configuration, tous les paramètres étant dans le fichier config.h — voir ce tutoriel.

Awesome

Awesome est un fork de dwm, et lui reste très proche dans l'esprit : même système de vues, même mise en page sur deux colonnes maître / auxiliaire. Il est plus complet que dwm, scriptable en Lua et configurable via un fichier externe. Il ne dispose pas encore d'un équivalent de dmenu (c'est prévu pour la version 3) : pour l'instant (version 2.3.1), il faut se créer un menu d'applications soi-même, et lancer les autres applications depuis un terminal.

Awesome est configurable via le fichier ~/.awesomerc. Contrairement à wmii et dwm, Awesome est prévu pour fonctionner avec des dispositions de clavier ayant les chiffres en accès direct (sélection / changement de vue), il faut donc reconfigurer les touches [1234567890] pour le bépo.

Plus de détails pour la version 3.x

Xmonad

Xmonad utilise dmenu et reprend le principe des deux zones maître / auxiliaire de dwm, mais il est beaucoup plus complet : les manipulations de fenêtres ne sont pas limitées à un système de colonnes, et on peut même libérer une partie de l'écran pour inclure un panel type KDE, Gnome ou Xfce4. De plus, Xmonad est très modulaire et dispose déjà de nombreuses extensions. C'est un projet relativement récent (première release en avril 2007), écrit dans le langage fonctionnel Haskell. Voir cet extrait de la configuration de Gaëtan (à peaufiner).

Récupérée de « https://bepo.fr/wiki/index.php?title=Vim&oldid=21199 »